编辑“Planet modding”（章节）

==Terraforming==

Terraforming is defined separately from planets in files found in ''common/terraform''. These are relatively straightforward definitions, but do need to be defined for each individual link between two planet types. That means, for example, if a modder wishes to add a new planet type that can be terraformed into anything and have anything terraformed into it they will have to define two links for each existing planet type, one to transform a given type into the new one, and one to transform the new one into each existing type. A basic example of a terraforming link definition can be seen below:

    terraform_link = {
        from = "pc_continental"
        to = "pc_tropical"
    
        energy = 2000
        duration = 1800
    
        condition = {
            has_technology = "tech_terrestrial_sculpting"
        }
    
        ai_weight = {
            weight = 0
        }
    }

Each link definition starts with the header <code>terraform_link</code> and then is followed by arguments determining the starting and ending planet classes for the terraforming operation. After that it is followed by the cost of the terraforming operation as well as how long the operation will take to complete. Afterwards the link has a <code>condition</code> block. This is used to determine what requirements are needed before a terraforming operation can be performed, and is used to lock certain transformations behind technology or ascension perks. Lastly a terraforming link definition includes an <code>ai_weight</code> entry, which is used to determine whether or not an AI will perform a terraforming.

If desired there are some slightly modifications that can be performed on the basic format. One is to use a <code>potential</code> block. When used this will cause the terraforming option to only appear if the listed requirements are met. For example, this terraforming link definition

    terraform_link = {
        from = "pc_barren_cold"
        to = "pc_arctic"
        
        energy = 5000
        duration = 3600
        
        potential = {
            from = { has_modifier = terraforming_candidate }
        }
        condition = {
            has_technology = "tech_climate_restoration"
        }
        
        effect = {
            from = { remove_modifier = terraforming_candidate }
        }
        
        ai_weight = {
            weight = 5
        }
    }

Will only show up in the menu if the pc_barren_cold planet also has the terraforming_candidate modifier, and will not be available otherwise.

A final note is that terraform_link's also support <code>effect</code> blocks as well. These are operations that are performed immediately upon completion of the terraforming operation. For example, adding this block:

    effect = {
        from = { remove_modifier = terraforming_candidate }
    }

Will cause the "terraforming_candidate" modifier to be removed from the terraformed planet upon completion.

{{Template:ModdingNavbox}}
[[Category:模组制作]]